Funciones de fecha en Excel: SIFECHA, DIA.LAB, FIN.MES y las que usarás cada día

Calcular la antigüedad de cada trabajador, saber qué facturas vencen esta semana o decirle a un cliente en qué fecha recibirá su pedido son tareas de todos los días. Las funciones de fecha en Excel las resuelven en una fórmula, siempre que sepas cuál usar en cada caso.

En esta guía trabajamos con un archivo con tres hojas: el personal de una empresa, sus facturas por cobrar y los plazos de entrega de sus pedidos. Las imágenes son capturas de ese archivo. Forma parte de nuestra sección de fórmulas y funciones. En las capturas, Excel usa el punto y coma para separar los argumentos y el punto para los decimales. Si tu configuración regional usa la coma, cambia los separadores al copiar las fórmulas.

Primero, cómo guarda Excel una fecha

Para Excel una fecha es un número: los días transcurridos desde el 1 de enero de 1900. El 31 de diciembre de 2026 es el número 46387. Por eso se pueden restar dos fechas para obtener los días entre ellas, o sumar 30 a una fecha para saber cuándo vence un crédito. Si una fórmula de fechas te devuelve un número de cinco cifras, no está mal: le falta el formato de fecha. Lo explicamos en formato de celdas.

HOY y la fecha de corte

=HOY() devuelve la fecha de hoy y se actualiza cada vez que abres el archivo. Es perfecta para alertas de vencimiento, pero tiene un inconveniente: un informe calculado con HOY() cambia de un día para otro y no se puede reproducir.

En los informes conviene usar una fecha de corte: una celda con la fecha a la que quieres calcular, en el ejemplo C2, y todas las fórmulas apuntando a $C$2. Si quieres que sea siempre hoy, escribe =HOY() en esa celda; si necesitas el informe al cierre de mes, escribe la fecha a mano. Para escribir la fecha actual como valor fijo, sin fórmula, usa el atajo Ctrl + ;.

FECHA, DIA, MES y AÑO: armar y desarmar fechas

• =FECHA(2026;7;1) construye el 1 de julio de 2026 a partir de año, mes y día. Es la forma segura de escribir una fecha dentro de una fórmula.
• =DIA(C5), =MES(C5) y =AÑO(C5) extraen cada parte de una fecha.
• Combinadas, resuelven casos útiles: =FECHA(AÑO(C5);MES(C5)+1;1) da el primer día del mes siguiente a C5.

Calcular la edad con SIFECHA

SIFECHA calcula el tiempo transcurrido entre dos fechas en la unidad que le pidas:

=SIFECHA(fecha_inicial;fecha_final;unidad)

La unidad es un texto entre comillas: "y" para años completos, "m" para meses completos, "d" para días, "ym" para los meses que sobran después de los años completos y "yd" para los días que sobran después de los años. En la hoja de personal, la edad a la fecha de corte es:

=SIFECHA(C5;$C$2;"y")

Con la fecha de corte en el 31 de diciembre de 2026, Ana Quispe, nacida el 14 de marzo de 1988, tiene 38 años, y Jorge Salas, nacido el 30 de enero de 1979, tiene 47. SIFECHA cuenta años completos: no redondea hacia arriba aunque falte un día para el cumpleaños.

Dos detalles que sorprenden la primera vez. SIFECHA no aparece en la lista de funciones al escribir ni muestra la ayuda de argumentos: es una función heredada que Excel mantiene por compatibilidad, pero funciona perfectamente. Y si la fecha inicial es posterior a la final, devuelve #¡NUM!. Evita además la unidad "md", que la propia Microsoft desaconseja porque puede dar resultados incorrectos.

Antigüedad en años y meses

Para mostrar la antigüedad como texto, une dos SIFECHA con el operador &:

=SIFECHA(D5;$C$2;"y")&" años y "&SIFECHA(D5;$C$2;"ym")&" meses"

Ana Quispe, que ingresó el 1 de junio de 2015, lleva 11 años y 6 meses; Miguel Huamán, que entró el 2 de marzo de 2026, 0 años y 9 meses. Fíjate en Carla Torres: «8 años y 1 meses». Para que el singular salga bien, sustituye el último trozo por &SI(SIFECHA(D5;$C$2;"ym")=1;" mes";" meses").

La última columna usa =TEXTO(D5;"dddd") para mostrar el día de la semana de cada ingreso. En este caso todos empezaron un lunes, algo habitual en muchas empresas.

Vencimientos de facturas

La hoja de facturas parte de la fecha de emisión y los días de crédito. Con la fecha de corte en el 10 de noviembre de 2026, estas son las fórmulas de la primera fila:

• Vencimiento: =C5+D5. Sumar días a una fecha es una suma normal.
• Días para vencer: =E5-$C$2. Un número negativo indica los días de atraso.
• Estado: =SI(F5<0;"Vencida";SI(F5<=7;"Por vencer";"Al día")), con la función SI anidada.

La factura F001-0412, emitida el 1 de octubre a 30 días, venció el 31 de octubre y lleva 10 días de atraso. La F001-0431, emitida el 28 de octubre a 15 días, vence el 12 de noviembre: le quedan 2 días y sale como «Por vencer».

FIN.MES y FECHA.MES: el último día y los meses exactos

Muchas empresas pagan o cobran «a fin de mes». =FIN.MES(C5;0) devuelve el último día del mes de la fecha en C5: para una factura del 9 de octubre, el 31 de octubre. Con 1 en lugar de 0, da el último día del mes siguiente, y con -1, el del mes anterior.

Para sumar meses exactos, en lugar de días, usa =FECHA.MES(C5;3): tres meses después de C5, el mismo día. Si ese día no existe, como el 31 de febrero, devuelve el último día del mes. Es la función adecuada para garantías, renovaciones y contratos.

Días hábiles con DIA.LAB y DIAS.LAB

Cuando un plazo se cuenta en días hábiles, sumar días no sirve: hay que saltarse los fines de semana y los feriados. Para eso hay dos funciones:

• =DIA.LAB(fecha_inicial;días;[vacaciones]) devuelve la fecha que resulta de avanzar ese número de días hábiles.
• =DIAS.LAB(fecha_inicial;fecha_final;[vacaciones]) cuenta los días hábiles que hay entre dos fechas, ambas incluidas.

El argumento opcional es un rango con los feriados. En la hoja de plazos hemos puesto, como ejemplo, el 28 y el 29 de julio y el 30 de agosto de 2026, y les hemos dado el nombre Feriados. La fecha de entrega de cada pedido es:

=DIA.LAB(B5;C5;Feriados)

Mira el pedido 1: se hace el jueves 23 de julio con un plazo de 5 días hábiles. Sin feriados, se entregaría el 30 de julio; con Fiestas Patrias, el 3 de agosto. El pedido 4, del viernes 24 de julio a 2 días hábiles, pasa del 28 al 30 de julio. Si prometes plazos sin descontar feriados, en julio y en diciembre fallarás.

La celda «Días hábiles de julio 2026» usa =DIAS.LAB(FECHA(2026;7;1);FIN.MES(FECHA(2026;7;1);0);Feriados) y devuelve 21: los 23 días laborables del mes menos los dos feriados. Es la base para repartir una meta mensual por día o calcular la productividad diaria.

La lista de feriados del ejemplo es parcial. En tu archivo, incluye todos los del año según el calendario oficial y añade los días no laborables que decrete el gobierno.

¿Y si trabajas los sábados?

DIA.LAB y DIAS.LAB dan por hecho que el fin de semana es sábado y domingo. Si tu negocio abre los sábados, usa sus versiones internacionales con el código de fin de semana 11, que significa «solo domingo»: =DIA.LAB.INTL(B5;C5;11;Feriados).

Otras funciones de fecha que conviene conocer

• =DIASEM(C5;2): el día de la semana como número, del 1 (lunes) al 7 (domingo). Útil para pintar los fines de semana o detectar entregas en domingo.
• =NUM.DE.SEMANA(C5;2): el número de semana del año, empezando la semana en lunes.
• =TEXTO(C5;"mmmm"): el nombre del mes, para agrupar o para títulos de informe.
• =DIAS(E5;C5): los días entre dos fechas. Equivale a restarlas.

Errores frecuentes con fechas

• Fechas guardadas como texto. Se alinean a la izquierda y ninguna función las reconoce. Suele pasar al pegar datos de otro sistema; lo arreglamos en limpiar datos pegados de otro sistema.
• Día y mes invertidos. Un archivo hecho con formato mes/día abierto en un equipo con día/mes convierte el 3 de abril en el 4 de marzo. Comprueba siempre una fecha con el día mayor que 12.
• #¡NUM! en SIFECHA. La fecha inicial es posterior a la final.
• Un número en lugar de una fecha. Es la fecha sin formato: Ctrl + 1 → Fecha.

Practica con un archivo real

El archivo gratuito de 7 fórmulas de Excel para el trabajo tiene un módulo dedicado a HOY para controlar vencimientos, entregas y días pendientes. Y si lo que necesitas es un control de plazos ya hecho, el registro de trámites y vencimientos calcula los días de atención y avisa de lo que está por vencer. Para encadenar tareas con fechas, mira cómo hacer un diagrama de Gantt en Excel.

Preguntas frecuentes

¿Por qué SIFECHA no aparece cuando la escribo?

Porque Excel la mantiene solo por compatibilidad y no la muestra en el autocompletado ni en el asistente de funciones. Escríbela completa y funcionará.

¿Cómo calculo los días entre dos fechas?

Resta la fecha menor a la mayor, =E5-C5, o usa DIAS. Si necesitas solo los días hábiles, DIAS.LAB.

¿Cómo sumo meses a una fecha?

Con FECHA.MES. Sumar 30 días no equivale a un mes: febrero tiene 28 días y otros meses 31.

¿Funcionan en Excel online?

Sí, todas las de esta guía, SIFECHA incluida, funcionan en Excel online.